*SUMADOR BRENT-KUNG:
*CELDA P/G DE PRIMER NIVEL
*GENERA LAS FUNCIONES Pi_n Gi_n A PARTIR DE Ai y Bi

.SUBCKT pg0 Ai Bi Pi_n Gi_n 1 0

*Transistores de pull-up de Gi_n
M1   1 Ai  Gi_n 1 tp L=1U W=4U AS=24P AD=24P PS=20U PD=20U 
M2   1 Bi Gi_n 1 tp L=1U W=4U AS=24P AD=24P PS=20U PD=20U

*Transistores de pull-down de Gi_n
M3   Gi_n Ai 2 0 tn L=1U W=4U AS=24P AD=24P PS=20U PD=20U 
M4   2 Bi 0 0 tn L=1U W=4U AS=24P AD=24P PS=20U PD=20U

*Transistores de pull-up de Pi_n
M5   1 Ai_n 3 1 tp L=1U W=8U AS=48P AD=48P PS=28U PD=28U
M6   1 Bi 3 1 tp L=1U W=8U AS=48P AD=48P PS=28U PD=28U
M7   3 Ai Pi_n 1 tp L=1U W=8U AS=48P AD=48P PS=28U PD=28U
M8   3 Bi_n Pi_n 1 tp L=1U W=8U AS=48P AD=48P PS=28U PD=28U

*Transistores de pull-down de Pi_n
M9   Pi_n Ai_n 5 0 tn L=1U W=4U AS=24P AD=24P PS=20U PD=20U
M10  5 Bi 0 0 tn L=1U W=4U AS=24P AD=24P PS=20U PD=20U
M11  Pi_n Ai 6 0 tn L=1U W=4U AS=24P AD=24P PS=20U PD=20U
M12  6 Bi_n 0 0 tn L=1U W=4U AS=24P AD=24P PS=20U PD=20U

*Transistores de pull-up de Ai_n
M13  1 Ai Ai_n 1 tp L=1U W=4U AS=24P AD=24P PS=20U PD=20U

*Transistores de pull-down de Ai_n
M14  Ai_n Ai 0 0 tn L=1U W=2U AS=12P AD=12P PS=16U PD=16U

*Transistores de pull-up de Bi_n
M15  1 Bi Bi_n 1 tp L=1U W=4U AS=24P AD=24P PS=28U PD=28U

*Transistores de pull-down de Bi_n
M16  Bi_n Bi 0 0 tn L=1U W=2U AS=12P AD=12P PS=16U PD=16U

.ENDS pg0